애니매이션 파일 만들기

C. Huber 가 Stata 블로그에 만들어 놓은 애니메이션 파일을 조금 수정하여 

기각역과 파워를 살펴볼 수 있는 파일을 만들었다.

local GraphCounter = 100

local mu_null = 0

local sd = 1

local z_crit = round(-1*invnormal(0.05), 0.01)

local z_crit_label = `z_crit' + 0.75

local color1 "pink%70"

local color2 "navy%70"

forvalues mu_alt = 1(0.03)3 {

  twoway  ///

    function y=normalden(x,`mu_null',`sd'),                    ///

             range(-3 `z_crit') color(`color1') dropline(0)   ||    ///

    function y=normalden(x,`mu_alt',`sd'),                     ///

             range(-3 5) color(`color2') dropline(`mu_alt') ||    ///

    function y=normalden(x,`mu_alt',`sd'),                     ///

             range(`z_crit' 6) recast(area) color(`color2') ||    ///

    function y=normalden(x,`mu_null',`sd'),                    ///

             range(`z_crit' 6) recast(area) color(`color1')         ///

    title("Power for {&mu}={&mu}{subscript:0} versus {&mu}={&mu}{subscript:1}", pos(12)) ///

    xtitle("{it: z}") xlabel(-3 -2 -1 0 1 2 3 4 5 6)           ///

    legend(off)                                                ///

    ytitle("Density") yscale(range(0 0.6))                     ///

    ylabel(0(0.1)0.6, angle(horizontal) nogrid)                ///

    text(0.45 0 "{&mu}{subscript:0}", color(`color1'))              ///

    text(0.45 `mu_alt' "{&mu}{subscript:1}", color(`color2')) scheme(538)

  graph export mu_alt_`GraphCounter'.png, as(png) width(1280) height(720) replace

  local ++GraphCounter

}

그러면 아래와 같은 애니매이션이 가미된 파일을 만들 수 있다.

생성된 그림 파일을 가지고 포토샵이나 무료 gif 생성 프로그램(https://ezgif.com) 등을 이용하면 아래와 같이 애니매이션이 가미된 그림을 그릴 수 있다.

<Power>

<Type I and Type II error>

<trade-off between type I and type II error>